*  JieJie Microelectronics P-Spice Model Library
*  Filename	: JMH65R190AF_P v.20220923.txt
*  Product Name   : JMH65R190AF (TO-220FP-3L)
*  Configuration:	: Single N-channel Device
*  Data Sheet Rev.	: 1.0
*  Release Date	: Sep 23, 2022
*  Junction Temp (Tj)	: -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMH65R190AF D G S
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
Vmonitor D 18 0
RD 18 1 0.17
RS S 3 1E-006
RG G 17 8.9
CGS 3 G 1.57E-9
EGD 12 0 2 1 1
Etemp 17 2 VALUE = {(-0.00642*(TEMP-25))+((-2.67861E-6)*(TEMP-25)^2)}
Gtemp 1 3  VALUE = {I(Vmonitor)*((TEMP+273)/(298)-((TEMP+273)/(298))^1.2)}

VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 1.1E-9
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
Cbreak D 3 Cbreak 3.17702E-9
.MODEL Cbreak CAP (C=1 VC1= -0.00743 VC2 = 1.01851E-5)

.model NMOS NMOS
+LEVEL = 3
+VMAX = 5.980848E6             ETA = 1.241069E-4
+VTO = 3.469326             TOX = 5.979588E-12            NSUB = 2.664003E19  
+KP =  20.980698                U0 = 7.528208E-4              KAPPA = 4.34272E-2
+GAMMA = 10                     THETA = -4.54521E-6       DELTA = 446.681452   
 
.model DCGD D
+CJO = 1.42E-9                 VJ = 6                        M = 1.8 
.model DSUB D
+IS = 7.493025E-13             N = 1.20079                   RS = 4.093437E-3 
+BV = 675
+xti = -1.569806E-4
.model DLIM D
+IS = 1E-4
.ends JMH65R190AF

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************
